bug lady;
int numAphids = 10;
int maxAphids = 10;
bug[] aphids = new bug[maxAphids];
PFont fontScore,fontWin,fontData;
int score = 0;
int flag = 1;
int boardWidth = 600;
int sideWidth = 300;
int boardHeight = 600;
PImage target;
int numLeaves = 200;
leaf[] leaves = new leaf[numLeaves];

//PImage bg;

void setup(){
  frameRate(30);
  size(boardWidth+sideWidth,boardHeight);
  background(255,255,255);
  lady = new bug(250,250,40);
  for(int i =0; i <numAphids; i++)
     aphids[i] = new bug();
  for(int i =numAphids; i <maxAphids; i++)
      aphids[i] = null;
  for(int i = 0; i < numLeaves; i++)
      leaves[i] = new leaf();
  fontWin = loadFont("Algerian-30.vlw");
  fontScore = loadFont("Algerian-24.vlw"); 
  fontData = loadFont("ArialNarrow-14.vlw");
  textFont(fontScore); 
}

void draw(){
//  image(target,0,0);
  background(20,200,20);
  for(int i =0; i < numLeaves; i++)
     leaves[i].drawLeaf();
  if(flag == 1){
    lady.move();
    lady.eat();
  }
  if(flag == 0 && keyPressed){
    score = 0;
    flag = 1;
    lady = new bug(250,250,40);
  }
  for(int i =1; i < maxAphids;i++){
    if(aphids[i] != null){
      aphids[i].move();
      aphids[i].display();
    }
  }
  lady.display();
  stroke(0);
  fill(250);
  rect(boardWidth,0,sideWidth,boardHeight);
  fill(0,0,0);
  textFont(fontScore);
  text("Score: " +score,boardWidth+sideWidth/4,30);
  calcStats();
  if(lady.get_radius() < 15){
    stroke(255,0,0);
    fill(0,0,0);
    textFont(fontWin);
    text("Your Score: " + score, width*.4,height*.5);
    textFont(fontScore);
    text("Press any key to play again ", width*.316,height*.54);
    flag = 0;
  }
}


class bug{
  float dx;
  float dy;
  float theta;
  float v;
  float dtheta;
  float x;
  float y;
  float radius;
  int type;
  int timer;
  color c;
  
  bug(float ix,float iy, float ir){
    // initialize the ladybug
     x = ix;
     y=iy;
     radius = ir;
     type = 0;
     timer=0;
     dx = 0.0;
     dy = -0.1;
  }
  
  bug(){
    // initialize aphids
    x=random(0,width);
    y=random(0,height);
    dx = random(-3.0,3.0);
    dy = 2+random(-3.0,3.0);
    radius = 17;
    type = 1;
    int(random(0,5));  
    v = random(1.0,4.0);
    theta = random(0,2*PI);
    dtheta = random(-0.05,0.05);
    c = color(random(0,255),random(10,255),random(0,255));
 }
  
  void eat(){
    float dist;
    for(int i = 0; i < maxAphids;i++){
      if(aphids[i] !=null){
        if(aphids[i].type!=0){
          dist = ((aphids[i].x-x)*(aphids[i].x-x)+(aphids[i].y-y)*(aphids[i].y-y));
          if(sqrt(dist)<(radius*.6)){
            aphids[i] = null; // erase old aphid
            score++;
          }
        }
      }
    }
  }
  
  void mutCopy(bug s){
    x=s.x;
    y=s.y;
    dx = s.dx;
    dy = s.dy;
    radius = s.radius+random(-0.5,0.5);
    if(radius < 3)
       radius = 3;  // minimum radius
    type = 1;  
    timer = int(random(0,5));
    v = s.v + random(-2.0,2.0);
    if(v < 0)
       v *=-1;  // maintain positive speed
    if(random(0,1.0) < 0.5)
       theta = s.theta + PI/4;
    else 
       theta = s.theta - PI/4;
    dtheta = s.dtheta + random(-0.01,0.01);
    int crange = 12;
    c = color(red(s.c)+random(-1*crange,crange)*random(-1*crange,crange),green(c),blue(c));
    c = color(red(c),green(s.c)+random(-1*crange,crange)*random(-1*crange,crange),blue(c));
     c = color(red(c),green(c),blue(s.c)+random(-1*crange,crange)*random(-1*crange,crange));
   }
  
  float get_radius(){
    return radius;
  }
  
  void move(){   
    int adjustMouseX = mouseX;
    if(adjustMouseX > boardWidth)
       adjustMouseX = boardWidth;  // avoids ladybug wrapping right
    if(type ==0){  // ladybug
       dx=0.3*(adjustMouseX-x);
       dy=0.3*(mouseY-y);
       if(dx > 10)
          dx = 10;
       if(dx < -10)
          dx = -10;
       if(dy > 10)
          dy = 10;
       if(dy < -10)
          dy = -10;
    }
    if(type == 0){  // ladbug
       x += dx; 
       y += dy; 
    }
    else{
      x+=(v*sin(theta));
      y+=(v*cos(theta));
      theta+=dtheta;
      dtheta+=(random(0.01)-0.005);
      timer++;
      if(timer == 20){  // parent
          timer = 0;
          int j=0;
          while(j < maxAphids && aphids[j] != null){
            j++;  // find null slot
          } // pick parent
          if(j < maxAphids){
             aphids[j] = new bug();
             aphids[j].mutCopy(this);
             numAphids++;
          }
      }
    }
    if(x < 0)
       x = boardWidth;
    if(x>boardWidth)
       x = 0;
    if(y < 0)
       y = boardHeight;
    if(y>boardHeight)
       y = 0;
  }
  
  void display() {
    if(type == 0)
       displaylady();
    else
       displayaphid();
  }
  
  void displaylady (){
    float angle = atan(dx/dy);
    if(dy<0)
       angle=angle+PI;
    stroke(0,0,0);
    fill(255,0,0);
    ellipse(x,y,radius,radius);
    line(x+(radius-1)/2*sin(angle),y+(radius-1)/2*cos(angle),x-(radius-1)/2*sin(angle),y-(radius-1)/2*cos(angle));
    fill(0,0,0);
    ellipse(x+(radius*0.5)*sin(angle),y+(radius*0.5)*cos(angle),radius*.25,radius*.25);
 ellipse(x+(radius)/4*sin(angle+PI/3),y+(radius)/4*cos(angle+PI/3),radius/5,radius/5);
 ellipse(x+(radius)/4*sin(angle-PI/3),y+(radius)/4*cos(angle-PI/3),radius/5,radius/5);
 ellipse(x+(radius)/4*sin(angle+2*PI/3),y+(radius)/4*cos(angle+2*PI/3),radius/5,radius/5);
 ellipse(x+(radius)/4*sin(angle-2*PI/3),y+(radius)/4*cos(angle-2*PI/3),radius/5,radius/5);
  } 
  
  void displayaphid(){
    if(type == 0)
       return;
    noStroke();
    fill(0,0,0);
    ellipse(x+(radius*0.5)*sin(theta-0.2),y+(radius*0.5)*cos(theta-0.2),radius*.25,radius*.25);
    ellipse(x+(radius*0.5)*sin(theta+0.2),y+(radius*0.5)*cos(theta+0.2),radius*.25,radius*.25);
    fill(c);
    ellipse(x,y,radius,radius);
  }
}  

void calcStats(){
  float avgV = 0;
  float avgTheta = 0;
  float avgDtheta = 0;
  int count = 0;
  for(int i = 0; i < maxAphids; i++){
    if(aphids[i] != null){
      count++;
      avgV+=aphids[i].v;
      avgTheta+=aphids[i].theta;
      avgDtheta+=aphids[i].dtheta;
    }
  }
  avgV /= count;
  avgTheta /= count;
  avgDtheta /= count;
  textFont(fontData);
  text("Average Aphid Speed = " + round(avgV*10)/10.0, boardWidth+sideWidth/2.0 - 100, 50);
//  text("Average Aphid Turn = " + round(avgTheta*10)/10.0, boardWidth+sideWidth/2.0 - 100, 75);
//  text("Average Aphid Delta Turn = " + round(avgDtheta*100)/100.0, boardWidth+sideWidth/2.0 - 100, 100);
}
      
class leaf{
  float x,y;
  float r1,r2;
  color c;
  
  leaf(){
    x = random(-10,boardWidth);
    y = random(-10,height);
    r1 = random(50,100);
    r2 = random(50,100);
    c = color(int(random(0,50)),int(random(180,220)),int(random(0,50)));
  }
  
  void drawLeaf(){
    stroke(c);
    fill(c);
    ellipse(x,y,r1,r2);
  }
}